专有网络与交换机

控制台

API

与控制台逻辑不同的是，使用CreateVpc仅创建一个空的专有网络，您还需要使用CreateVSwitch创建交换机。

• 依次调用CreateVpc和CreateVSwitch创建专有网络和交换机。

• 依次调用DeleteVSwitch和DeleteVpc删除交换机和专有网络。

  1、删除交换机前，需要确保交换机未共享、未绑定自定义路由表和网络ACL并且交换机内的云产品资源已释放。

  2、删除专有网络前，需要确保VPC内资源已释放完成，且已取消与云企业网等网络服务的关联。

Terraform

Resources：alicloud_vpc、alicloud_vswitch

Data Sources：alicloud_zones

# 指定创建VPC的地域
provider "alicloud" {
  region = "cn-hangzhou"
}

# 根据数据源自动获取可以创建交换机的可用区列表
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # 查询VPC内可创建的可用区
  # available_instance_type = "ecs.g7.large"  # 查询VPC内可创建ECS实例的可用区
  # available_resource_creation = "slb"  # 查询VPC内可创建SLB实例的可用区
}

# 创建VPC 
resource "alicloud_vpc" "example_vpc" {
  vpc_name   = "example_vpc_name"
  cidr_block = "10.0.0.0/16" #指定网段 
}

# 创建交换机 
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name = "example_vswitch_name"
  cidr_block   = "10.0.0.0/24"                                  # 指定网段 
  vpc_id       = alicloud_vpc.example_vpc.id                       # 指定交换机所属VPC的实例ID 
  zone_id      = data.alicloud_zones.available_zones.zones.0.id # 指定交换机所属可用区
}

控制台

API

• 创建专有网络和交换机时，调整CreateVpc和CreateVSwitch的EnableIPv6参数开启/关闭IPv6。

• 针对已创建的专有网络和交换机，调整ModifyVpcAttribute与ModifyVSwitchAttribute的EnableIPv6参数开启/关闭IPv6。

Terraform

Resources：alicloud_vpc、alicloud_vswitch

Data Sources：alicloud_zones

# 指定创建VPC的地域
provider "alicloud" {
  region = "cn-hangzhou"
}

# 根据数据源自动获取可以创建交换机的可用区列表
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # 查询VPC内可创建的可用区
  # available_instance_type = "ecs.g7.large"  # 查询VPC内可创建ECS实例的可用区
  # available_resource_creation = "slb"  # 查询VPC内可创建SLB实例的可用区
}

# 创建双栈VPC 
resource "alicloud_vpc" "example_vpc" {
  vpc_name    = "example_vpc_name"
  cidr_block  = "10.0.0.0/16"
  enable_ipv6 = true  # 开启IPv6，false为关闭IPv6
  ipv6_isp    = "BGP" # 指定IPv6网段类型
}

# 创建双栈交换机 
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name         = "example_vswitch_name"
  cidr_block           = "10.0.0.0/24"
  vpc_id               = alicloud_vpc.example_vpc.id
  zone_id              = data.alicloud_zones.available_zones.zones.0.id
  enable_ipv6          = true # 开启IPv6，false为关闭IPv6
  ipv6_cidr_block_mask = 1    # 指定交换机IPv6网段的最后8比特位 
} 

控制台

API

• 调用AssociateVpcCidrBlock添加附加网段。

• 调用UnassociateVpcCidrBlock删除附加网段。

Terraform

Terraform当前仅支持创建IPv4附加网段，暂不支持创建IPv6附加网段。

Resources：alicloud_vpc_ipv4_cidr_block

# 指定创建VPC的地域
provider "alicloud" {
  region = "cn-hangzhou"
}

# 指定VPC的ID
variable "vpc_id" {
  default = "vpc-xxx" # 修改为VPC的实际ID
}

# 在VPC中创建附加网段
resource "alicloud_vpc_ipv4_cidr_block" "example_secondary_cidr_block" {
  vpc_id               = var.vpc_id
  secondary_cidr_block = "192.168.0.0/16" # 指定附加网段
}

控制台

API

• 调用CreateVSwitchCidrReservation创建预留网段。

• 调用GetVSwitchCidrReservationUsage查看已占用IP段。

• 调用DeleteVSwitchCidrReservation删除预留网段。

Terraform

Resources: alicloud_vpc_vswitch_cidr_reservation

# 指定创建VPC的地域
provider "alicloud" {
  region = "cn-hangzhou" # 资源所在的地域
}

# 指定交换机的ID
variable "vsw_id" {
  default = "vsw-xxx" # 修改为交换机的实际ID
}

# 创建预留网段
resource "alicloud_vpc_vswitch_cidr_reservation" "example_cidr_reservation" {
  vswitch_id                    = var.vsw_id 
  ip_version                    = "IPv4" 
  cidr_reservation_cidr         = "10.0.0.128/26" # 指定预留网段 
}

控制台

前往专有网络控制台的创建专有网络页面，使用IPAM分配的IPv4地址段，选择IPAM地址池并配置掩码，从IPAM地址池中为专有网络分配网段。

配置网络掩码后，系统会默认分配指定掩码范围内第一个可用的CIDR，您也可以在地址池预置CIDR内，调整IPv4网段。

创建专有网络前，请确保已通过IPAM控制台创建IPAM和IPAM地址池。

API

• 如已创建过IPAM地址池，可在调用CreateVpc时传入Ipv4IpamPoolId来指定IPAM地址池，同时传入Ipv4CidrMask来指定掩码从IPAM地址池中分配地址作为新建VPC的网段。您也可以传入CidrBlock来指定VPC使用的网段，而不是通过指定掩码自动分配网段。

• 如未创建过IPAM地址池，可依次调用如下API来创建IPAM地址池，然后参考上述逻辑创建专有网络。

  1. OpenVpcIpamService-开通IPAM功能

  2. CreateIpam-创建一个IPAM实例

  3. CreateIpamPool-创建IPAM地址池

  4. AddIpamPoolCidr-为IPAM地址池预置CIDR地址段

Terraform

Resources：vpc_ipam_ipam、alicloud_vpc_ipam_ipam_pool、alicloud_vpc_ipam_ipam_pool_cidr、alicloud_vpc

# 指定创建IPAM、IPAM 地址池、VPC的地域
provider "alicloud" {
  region = "cn-hangzhou"
}

# 创建IPAM
resource "alicloud_vpc_ipam_ipam" "example_ipam" {
  ipam_name             = "example_ipam_name"
  operating_region_list = ["cn-hangzhou"] # 指定IPAM的生效地域
}

# 创建IPAM地址池
resource "alicloud_vpc_ipam_ipam_pool" "example_parentIpamPool" {
  ipam_scope_id  = alicloud_vpc_ipam_ipam.example_ipam.private_default_scope_id # 指定IPAM地址池的作用范围
  ipam_pool_name = "example_parentIpamPool_name"
  pool_region_id = alicloud_vpc_ipam_ipam.example_ipam.region_id # 指定IPAM地址池的生效地域
  ip_version     = "IPv4"                                     # 指定IPAM地址池的版本
}

# 为IPAM地址池分配CIDR
resource "alicloud_vpc_ipam_ipam_pool_cidr" "example_ipamPoolCidr" {
  cidr         = "10.0.0.0/16"                                       # 指定CIDR
  ipam_pool_id = alicloud_vpc_ipam_ipam_pool.example_parentIpamPool.id # 指定IPAM地址池的ID
}

# 创建VPC
resource "alicloud_vpc" "example_ipam_vpc" {
  vpc_name          = "example_ipam_vpc_name"
  ipv4_ipam_pool_id = alicloud_vpc_ipam_ipam_pool.example_parentIpamPool.id # 指定IPAM地址池的ID
  ipv4_cidr_mask    = 24                                                 # IPv4网络掩码
}